VN ms fnc tracker spawnGroup

← back to Functions

Introduced in S.O.G. Prairie Fire v1.00 by Wyqer, veteran29

Argument(s): n/a Effect(s): unknown

Description

/*
    Author: Wyqer, veteran29
    Date: 2019-07-31

    Description:
        No description added yet.

    Parameter(s):
        _localVariable - Description [DATATYPE, defaults to DEFAULTVALUE]

    Returns:
        Function reached the end [BOOL]
*/
params [
    ["_position", [0,0,0], [[]], [2,3]],
    ["_alert", 0, [0]],
    ["_side", EAST, [sideUnknown]],
    ["_army", "VN", [""]]
];

private _alertCfg = configFile >> "CfgTrackerArmies" >> _army >> format ["alert_%1", _alert];
if (isNull _alertCfg) then {
    [format ["No CfgTrackerArmies entry for army: '%1' and alert '%2'", _army, _alert]] call BIS_fnc_error;
};

// Append 0z to Position2D
if (2 == count _position) then {
    _position = _position + [0];
};

private _group = createGroup [_side, true];

// create vehicles
{
    private _vehicle = createVehicle [_x, _position, [], 15, "FORM"];
    createVehicleCrew _vehicle;
    crew _vehicle joinSilent _group;
    _group addVehicle _vehicle;
} forEach selectRandom getArray (_alertCfg >> "vehicles");

// create units
{
    private _infantryUnit = _group createUnit [_x, _position, [], 5, "FORM"];
    _infantryUnit call vn_ms_fnc_aiSetSkill;
} forEach selectRandom getArray (_alertCfg >> "units");

{
    _x triggerDynamicSimulation false;
} forEach units _group;

_group

(Placeholder description extracted from the function header by LM_exportFunctionsToWiki.sqf)

Syntax

Syntax

[] call vn_ms_fnc_tracker_spawnGroup

Return value

Nothing

Examples

Example 1

-